Masquer #N/A suite à recherche V
Bonjour,
je souhaite ne pas afficher le #N/A qui apparait lorsque la valeur cherchée n'est pas présente dans la table matrice.
Je ne sais pas comment masquer cette valeur erronnée. J'avais pensé à intégrer la condition "si" mais je ne sais pas ou ni avec quelle référence.
Merci de votre aide.
Bonjour,
Avec la Fonction ESTNA :
=SI(ESTNA(RECHERCHEV(valeur_cherchée;table_matrice;no_index_col;valeur_proche));"";RECHERCHEV(valeur_cherchée;table_matrice;no_index_col;valeur_proche))Bonne journée
oSMoZ
Merci,
Chapeau, rapide et efficace.
Juste quelque parenthèses à modifier et c'est bon !
Bonjour,
J'ai utilisé ce code pour une recherche référence-désignation d'article-produit qui fonctionne a merveille. A la différence que j'ai une information qui s'affiche avec la mention " Réf inconnue " quand le N° de référence ne fais pas partie de la base de donnée. Malheureusement l'information s'affiche aussi quand la "valeur_cherchée" est vide aussi sans no de référence.
=SI(ESTNA(RECHERCHEV(valeur_cherchée;table_matrice;no_index_col;valeur_proche));"Réf. Inconnue";RECHERCHEV(valeur_cherchée;table_matrice;no_index_col;valeur_proche))
Y a t'il une possibilité d'avoir les 2 fonctions en même temps a savoir.
1) cellule vide ne rien affiché
2) N° de référence erroné mention de " Réf inconnue "
Merci d'avance
Bonsoir et bienvenue
=SI(ESTNA(RECHERCHEV(A1;table_matrice;2;0));"Réf inconnue";SI(RECHERCHEV(A1;table_matrice;2;0)=0;"";RECHERCHEV(A1;table_matrice;2;0)))Amicalement
Nad
Merci pour la réponse malgré l'heure c'est top. je viens de le tester la fonction réf inconnue fonctionne sans problème mais quand la cellule est vide l'info reste encore ref. inconnue.
je te met ma ligne de commande. je pense ne pas avoir fais d'erreur lors de la recopie a moins que....
peu tu me dire ce que tu en pense et ou serait l éventuelle problème.
Merci d'avance
=SI(ESTNA(RECHERCHEV(L12;Articles!$A$4:$F$503;2;0));"Réf. Inconnue";SI(RECHERCHEV(L12;Articles!$A$4:$F$503;2;0)=0;"";RECHERCHEV(L12;Articles!$A$4:$F$503;2;0)))
Bonjour
La formule est bonne.
Fais bien attention à l'orthographe de ce que tu inscris en L12 ; est-ce vraiment égal à une donnée de la matrice?
Dans le fichier joint, TEST4 renvoie "Ref inconnue" bien qu'on trouve TEST4 dans la matrice ; sauf que comme il y a un espace en trop après le 4, on n'a plus l'équivalence.
Amicalement
Nad
Merci pour la réponse.
J'ai compris ce que tu me disait pour l'éventuelle espace en trop qui adviendrait dans la base je ferai attention dans la création de la base.
Par contre c'est pas tous a fais ça mon problème.
j'aimerai que quand la case L12 soit vide que aucun N° de réf ne soit noté (Cellule vierge), la cellule de la désignation (A1 dans ton fichier test) sois aussi vide
Dans l'exemple de ton fichier si j'efface les référence "Test" dans la case jaune elle affiche aussi "Réf. Inconnue"
Re
OK - Par "cellule vide" je n'avais pas compris L12, mais la réponse à la RECHERCHEV
=SI(L12="";"";SI(ESTNA(RECHERCHEV(L12;Articles!$A$4:$F$503;2;0));"Réf. Inconnue";RECHERCHEV(L12;Articles!$A$4:$F$503;2;0)))Et comme tu es sous 2010, cette formule plus courte :
=SI(L12="";"";SIERREUR(RECHERCHEV(L12;Articles!$A$4:$F$503;2;0);"Réf. Inconnue"))Amicalement
Nad
Merci beaucoup cette fois c'était la bonne formule.
ça fonctionne nickel... ou presque.
j'ai juste un problème de compatibilité avec une autre formule ( I12 ) qui croise cette formule une toute simple soustraction ou soit j'ai la mention "#N/A" ou "#VALEUR!" suivant le type de formule que j'ai posé dans la colonne J. il faudrait aussi que dans cette colonne si il n'y a pas de donnée a affiché la Cellule reste vierge aussi quand il n'y a pas de reférence en ( L12 ), quel formule serai a modifier ?
j’espère que le petit exemple que je t'est joint t'aidera a comprendre plus facilement de quoi je parle
Re
Si j'ai bien compris :
=SIERREUR(M12-J12;"")Formule à tirer vers le bas
Nad
C'est parfait
Merci infiniment