Séparer chaque mot d'une phrase en une cellule distincte

bonjour

serait-il possible de séparer les mots d'une phrase en cellule ?

ex en A1 = il fait beau

le resultat est

B1 = il

B2 = fait

B3 = beau

ou dans la même forme séparer les lettres d'un mot style le jeu motus

merci

Bonjour et bienvenue sur le forum,

Oui c'est possible en passant par Données -> Convertir (option Délimité) -> Suivant -> Cocher "Espace" -> Terminer

Bonjour,

Pour séparer les lettres d'un mot présent en A1, la formule suivante en B1 :

=STXT($A$1;COLONNE()-1;1)

à recopier vers la droite.

A+

Bonsoir

une formule de michelXLD

=SI(COLONNE()-1>NBCAR($A$7)-NBCAR(SUBSTITUE($A$7;" ";""));DROITE($A$7;NBCAR($A$7)-TROUVE("^^";SUBSTITUE($A$7;" ";"^^";NBCAR($A$7)-NBCAR(SUBSTITUE($A$7;" ";"")))));SI(COLONNE()-1=1;STXT($A$7;1;TROUVE("^^";SUBSTITUE($A$7;" ";"^^";1))-1);STXT($A$7;TROUVE("^^";SUBSTITUE($A$7;" ";"^^";COLONNE()-1-1))+1;TROUVE("^^";SUBSTITUE($A$7;" ";"^^";COLONNE()-1))-TROUVE("^^";SUBSTITUE($A$7;" ";"^^";COLONNE()-1-1))-1)))

La phrase se trouve en A7, la formule en B et tirer vers la droite

Bonsoir

Quasiment identique, adaptée à ta demande :

en B1 :

=SI(NBCAR($A$1)-NBCAR(SUBSTITUE($A$1;" ";""))+1<LIGNES($1:1);"";SI(LIGNES($1:1)>NBCAR($A$1)-NBCAR(SUBSTITUE($A$1;" ";""));DROITE($A$1;NBCAR($A$1)-TROUVE("^^";SUBSTITUE($A$1;" ";"^^";NBCAR($A$1)-NBCAR(SUBSTITUE($A$1;" ";"")))));SI(LIGNES($1:1)=1;STXT($A$1;1;TROUVE("^^";SUBSTITUE($A$1;" ";"^^";1))-1);STXT($A$1;TROUVE("^^";SUBSTITUE($A$1;" ";"^^";LIGNES($1:1)-1))+1;TROUVE("^^";SUBSTITUE($A$1;" ";"^^";LIGNES($1:1)))-TROUVE("^^";SUBSTITUE($A$1;" ";"^^";LIGNES($1:1)-1))-1))))

A tirer vers le bas

Amicalement

Nad

merci a tous

chaque de vos réponses m'ont permis d'adapter ce que je voulais faire