Envoi onglet spécifique au format .pdf
Bonjour,
J'ai un fichier Excel avec différentes macro qui me permettent d'envoyer des demandes par mail avec le document en PJ sous le format Excel.
Hors cette fois, j'aurai besoin de la même facon d'envoyer un mail mais avec comme pièce jointe un onglat spécifique au format pdf (onglat "avenant TP thérapeut).
Je ne sais pas trop comment m'y prendre pour lui dire de transformer l'onglet en pdf.
Voici la macro actuelle :
Sub emailhrbp()
'
Application.DisplayAlerts = False
ActiveWorkbook.SaveAs Filename:="C:\Temp\Organisation du temps de travail TP thérapeutique.xlsm"
Application.DisplayAlerts = True 'Remettre absolument ensuite
Dim olApp As Outlook.Application
Set olApp = CreateObject("outlook.application")
Dim olMail As Outlook.MailItem
'Set olMail = olApp.CreateItem(olMailItem)
Set olMail = olApp.CreateItemFromTemplate("\\vcn.ds.volvo.net\cli-sd\sd1168\042595\Matrices\Maladie\Mi temps thérapeutique\Trame décomposition Tp thérapeutique pour manager\Modèle envoi avenant TPT pour HRBP.msg")
With olMail
.To = Range("O3").Value 'manager
.Subject = Range("B1").Value 'le sujet du mail
.Attachments.Add "C:\Temp\Organisation du temps de travail TP thérapeutique.xlsm" 'le fichier en PJ
.SendUsingAccount = olApp.Session.Accounts.Item(2) 'boîte fonctionnelle maladie
.Display 'affiche le mail pour vérification
End With
On Error GoTo 0
Set olMail = Nothing
Set olApp = Nothing
ActiveWorkbook.Close SaveChanges:=False 'sans sauvegarde
End Sub
je vous joins également le fichier en PJ
Merci d'avance pour votre aide.
Cédric
Bonjour pitochico;
vois si ça te convient:
Sub emailPDF()
Dim Chemin As String, MonFichier As String
Chemin = "C:\Temp\" 'A' ADAPTER SI NECESSAIRE
MonFichier = Chemin & "Organisation du temps de travail TP thérapeutique.PDF"
ActiveWorkbook.Sheets("Avenant TP thérapeut").ExportAsFixedFormat _
Type:=xlTypePDF, _
Filename:=MonFichier, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=False
Dim olApp As Outlook.Application
Set olApp = CreateObject("outlook.application")
Dim olMail As Outlook.MailItem
'Set olMail = olApp.CreateItem(olMailItem)
Set olMail = olApp.CreateItemFromTemplate("\\vcn.ds.volvo.net\cli-sd\sd1168\042595\Matrices\Maladie\Mi temps thérapeutique\Trame décomposition Tp thérapeutique pour manager\Modèle envoi avenant TPT pour HRBP.msg")
With olMail
.To = Range("O3").Value 'manager
.Subject = Range("B1").Value 'le sujet du mail
.Attachments.Add MonFichier 'le MonFichier en PJ
.SendUsingAccount = olApp.Session.Accounts.Item(2) 'boîte fonctionnelle maladie
.Display 'affiche le mail pour vérification
End With
On Error GoTo 0
Set olMail = Nothing
Set olApp = Nothing
Kill MonFichier 'Supprimer le fichier PDF
'ActiveWorkbook.Close SaveChanges:=False 'sans sauvegarde
End Sub
Hello,
It's perfect ! exactement ce que j'avais besoin
Un grand merci pour ton aide, je vais pour avancer plus rapidmeent pour envoyer mes avenants grace à toi.
bonne journée.
cédric