Copier cellule selon le nom des feuilles

Bonjour Famille,

Je tiens à préciser que je suis novice en vba, cependant j'ai besoin d'automatiser mes fichiers.

J'ai un classeur avec plusieurs feuilles, chaque feuille porte le nom d'un article sauf une feuille qui s'appelle "source" qui est en première position et dans cette feuille on a 2 colonnes: "nom article" et "quantité vendu". je veux que ecrire une macro qui fera:

si le nom de la feuille = au nom de la 2 eme cellule de la premiere colonne de "source", qu'elle copie la valeur de la celule d'en face pour l'envoyer dans la cellule B15 de la feuille correspondante et le faire pour toutes les feuilles du classeur sauf pour "source"

Est ce que quelqu'un a une idée ? merci encore pour votre aide précieuse

Bonjour Moimar, bonjour le forum,

Peut-être comme ça :

Sub Macro1()
Dim OS As Worksheet 'déclare la variable OS (Onglet Source)
Dim TV As Variant 'déclare la variable TV (Tableau des Valeurs)
Dim I As Integer 'déclare la variable I (Incrément)
Dim O As Worksheet 'déclare la variable O (Onglet)

Set OS = Worksheets("Source") 'définit l'onglet source OS
TV = OS.Range("A1").CurrentRegion 'définit le tableau des valeurs TV
For I = 2 To UBound(TV, 1) 'boucle sur toutes les lignes I du tableau des valeurs TV (en partant de la seconde)
    On Error Resume Next 'gestion des erreurs (en cas d'erreur, passe à la ligne suivante)
    Set O = Worksheets(TV(I, 1)) 'définit l'onglet O (génère une erreur si cet onglet n'existe pas)
    If Err <> 0 Then 'condition : si une erreur a été générée
        Err.Clear 'supprime l'erreur
        GoTo suite 'va à l'étiquette "suite"
    End If 'fin de la condition
    O.Range("B15").Value = TV(I, 2) 'renvoie la donnée ligne I colonne 2 de TV dans la cellule B15 de l'onglet O
suite: 'étiquette
    On Error GoTo 0 'annule la gestion des erreurs
Next I 'prochaine ligne de la boucle
End Sub

Bonjour Tautheme,

Mille merci pour ce code précieux qui me fera avancer dans mes tâches, il marche super bien, merci encore.

Cordialement!