Bonjour
Bonjour,
Je suis à la recherche d'une formule me permettant de me positionner en fonction d'une tranche (ci joint mon fichier)
Je souhaiterais qu'en indiquant un revenu et nombre de part dans les cellule A2 et B2 de l'onglet 1, s'affiche en celluel C2 :
- Total, si mon revenu est inférieur à la colonne B de l'onglet 2
- partielle, si je me situe entre la colonne B et C
- Aucune minorée, si je me situe entre la colonne C et D
- Aucune si je me situe au delà de la colonne D.
Quelqu'un arriverait-il à m'aider.
Merci d'avance
Salut,
Voici une solution avec une formule à rallonge.
=SIERREUR(CHOISIR(EQUIV(RECHERCHEH($A$2;DECALER('MinMax Fiscaux'!$B$2:$D$2;EQUIV('Saisie Usager'!$B$2;'MinMax Fiscaux'!$A$2:$A$13;0)-1;0;1);1;VRAI);DECALER('MinMax Fiscaux'!$B$2:$D$2;EQUIV('Saisie Usager'!$B$2;'MinMax Fiscaux'!$A$2:$A$13;0)-1;;1);0);"Partiel";"Aucune Minorée";"Aucune");"Totale")
Si tu veux des infos sur le fonctionnement, n'hésites pas...
Bonjour
Formule en C2
=CHOISIR(SIERREUR(EQUIV($A$2;DECALER('MinMax Fiscaux'!$B$1:$D$1;EQUIV($B$2;'MinMax Fiscaux'!$A$2:$A$13;0););1);0)+1;"Totale";"Partielle";"Aucune minorée";"Aucune")Cordialement
et oui... c'est plus simple...
Merci beaucoup, les formules fonctionnent.
Effectivement je veux bien quelques explications pour mieux me débrouiller la prochaine fois si vous avez un peu de temps pour me l'expliquer.
Merci beaucoup
Pour expliquer la formule de Amadéus, qui est plus simple:
=CHOISIR(SIERREUR(EQUIV($A$2;DECALER('MinMax Fiscaux'!$B$1:$D$1;EQUIV($B$2;'MinMax Fiscaux'!$A$2:$A$13;0););1);0)+1;"Totale";"Partielle";"Aucune minorée";"Aucune")
EQUIV($B$2;'MinMax Fiscaux'!$A$2:$A$13;0)
==> il cherche le numéro de la ligne avec le nombre de part choisi (il recherche la valeur exacte - option 0 à la fin de la formule)
==> renvoie un numéro de 1 à 12 (pour 3 parts,5ème ligne)
DECALER('MinMax Fiscaux'!$B$1:$D$1;EQUIV($B$2;'MinMax Fiscaux'!$A$2:$A$13;0);)
==> il décaler la première ligne du tableau avec les encadrements du nombre de ligne trouvé précédemment.
==> Pour 3 part, il renvoie la plage $B$6:$D$6
EQUIV($A$2;DECALER('MinMax Fiscaux'!$B$1:$D$1;EQUIV($B$2;'MinMax Fiscaux'!$A$2:$A$13;0););1)
==> dans cette nouvelle ligne, il cherche la colonne correspondant au montant directement inférieur au montant renseigné par l'utilisateur (-option 1 à la fin de la formule)
==> dans la ligne $B$6:$D$6, il renvoie les valeurs suivantes:
#N/A pour un montant < 23382
1 pour un montant < 30566
2 pour un montant <47437
3 pour un montant > 47437
SIERREUR(EQUIV($A$2;DECALER('MinMax Fiscaux'!$B$1:$D$1;EQUIV($B$2;'MinMax Fiscaux'!$A$2:$A$13;0););1);0)
==>si la formule précédente renvoi un numéro, alors, on garde ce numéro, par contre, s'il ne trouve pas de numéro de colonne (ce qui sera le cas pour un montant inférieur à la fourchette basse), la formule SIERREUR renvoie 0.
==> la formule SIERREUR renverra
0 si #N/A ou 1, 2 ou 3 pour les autres cas
CHOISIR(SIERREUR(EQUIV($A$2;DECALER('MinMax Fiscaux'!$B$1:$D$1;EQUIV($B$2;'MinMax Fiscaux'!$A$2:$A$13;0););1);0)+1;"Totale";"Partielle";"Aucune minorée";"Aucune")
==> dans la fonction CHOISIR, il rajoute 1 au numéro renvoyer par la fonction SIERREUR (du coup, on a 1, 2, 3 ou 4). en fonction de cette valeurs, on renvoie "total" si 1, "partiel" si 2, "Aucune minorée" si 3, "Aucune" si 4
Merci beaucoup pour les explications.
J'espère réussir à faire de super formules à l'avenir.