Erreur d'exécution '1004' - Création tableau de données

Bonjour à tous,

Je suis ici afin de solliciter votre aide. Je rencontre l'erreur suivante :

"Erreur d’exécution "1004' : Erreur définie par l'application ou par l'objet"

Lors de l’exécution du code suivant :

Option Explicit
Public TableauDonnees As Variant
Sub DataTableau(feuille As String, ligne As Long, colonne As Long)

    'Déclaration des variables
    Dim r As Long
    Dim c As Long
    Dim ligneTableau As Long
    Dim colonneTableau As Long
    Dim plage As Range

    'Traitement de la fonction
    For r = ligne To 1000000
        If ActiveWorkbook.Sheets(feuille).Cells(r, colonne).Value = "" Then
            Exit For
        Else
            ligneTableau = r
        End If
    Next
    For c = colonne To 1000000
        If ActiveWorkbook.Sheets(feuille).Cells(ligne, c).Value = "" Then
            Exit For
        Else
            colonneTableau = c
        End If
    Next
    TableauDonnees = ActiveWorkbook.Sheets(feuille).Range(Cells(ligne + 1, colonne), Cells(ligneTableau, colonneTableau)).Value

End Sub

Le débogage montre que l'erreur arrive à la dernière ligne.

Merci par avance.

Bonjour Lyamerwan et

Pour ma part, je ferais comme ça

Option Explicit
Public TableauDonnees() As Variant

Sub DataTableau(MaFeuille As Worksheet, Ligne As Long, Colonne As Long)
    'Déclaration des variables
    Dim LigneTableau As Long
    Dim ColonneTableau As Long
    'Traitement de la fonction
    LigneTableau = MaFeuille.Cells(Rows.Count, Colonne).End(xlUp).Row
    ColonneTableau = MaFeuille.Cells(Ligne, Columns.Count).End(xlToLeft).Column
    TableauDonnees = MaFeuille.Range(MaFeuille.Cells(Ligne + 1, Colonne), MaFeuille.Cells(LigneTableau, ColonneTableau)).Value
End Sub

En appelant la sub avec l'objet Worksheet et non juste son nom

A+

Merci beaucoup pour l'accueil et pour la réponse.