Voir la valeur d'une cellule simplement

Bonjour,

Après moult recherche je ne parviens pas à trouver une solution SIMPLE (j'insiste vraiment sur ce point) pour mon problème qui reste finalement assez bête.

J'ai un cellule qui concatène plusieurs autres cellules contenant du texte. Cette cellule est d'une certaine taille qui ne doit pas changer et le texte concaténer peut dépasser de la cellule et donc n'être pas visible entièrement.

J'aimerai tout simplement pouvoir visualiser la valeur affiché (le texte donc) de cette cellule en entier de manière simple, cela ne sera que ponctuel.

Pour éviter des incompréhension: je ne cherche pas à adapter la taille de la cellule au texte concaténer, ni à afficher cacher la formule.

Merci pour vos réponses.

Bonjour,

En clair tu veux pouvoir voir la totalité de ton texte sans avoir à affecter ta cellule, un moyen simple serait de passer par les commentaires, on peut utiliser un petit code VBA pour mettre en commentaire la valeur de la cellule sur un clic de celle-ci, tu pourrais ainsi la voir...

Je te donne un exemple dont voici le code:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Not Intersect(Target, Range("a1")) Is Nothing Then
    On Error Resume Next
    Range("a1").ClearComments
    Range("a1").AddComment Range("a1").Value
End If
End Sub

Il faut cliquer sur A1 pour mettre à jour le commentaire (comme tu voulais faire simple il faudra procéder comme ça).

Le fichier:

Merci pour cette réponse rapide je vais essayer ta solution.

Donc ce que j'en conclut c'est qu'il n'existe au final pas de façon d'accéder facilement à la valeur d'une cellule sans la modifier ? Par là j'entends pouvoir faire comme un agrandissement temporaire juste pour voir la cellule avec le contenu en entier sans la modifier.

Re,

Si tu veux faire ça ça peut se bidouiller aussi... je te propose ce code:

Public hauteur, largeur
Public cellule As Range

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Not Intersect(Target, Range("c2")) Is Nothing Then
    Cancel = True
    hauteur = Target.RowHeight
    largeur = Target.ColumnWidth
    Set cellule = Target

    Target.EntireColumn.AutoFit
    Target.EntireRow.AutoFit
End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If cellule Is Nothing Then Exit Sub
If Not Intersect(cellule, Range("c2")) Is Nothing Then
    cellule.RowHeight = hauteur
    cellule.ColumnWidth = largeur

    Set cellule = Nothing
End If
End Sub

et le fichier:

ça marche de la façon suivante : tu double clique sur ta cellule et ça la redimensionne en enregistrant temporairement son ancienne hauteur et son ancienne longueur, quand tu changes de sélection, la cellule retrouve sa hauteur et sa largeur de départ.

Merci beaucoup pour ces deux méthodes (qui fonctionne super bien !)

Je pense que je vais très souvent m'en resservir !

Rechercher des sujets similaires à "voir valeur simplement"