Coller de Excel vers Word sans le tableau

Bonjour à tous,

Je débute dans VBA ...

J'aimerais simplement copier ma colonne B dans Word mais je n'arrive pas à simplement coller le texte sans le tableau.

J'ai collecté plusieurs infos et voici le code qui fonctionne en parti mais garde toujours le tableau.

En gros je veux que mon tableau se transforme en simple lignes dans word.

Quelqu'un peut-il m'aider ?

Sub Bouton_ClicExceltoWordsimple()
Set word = CreateObject("Word.Application")
word.Documents.Add
word.Visible = True
'selectioner les cellules de la colonne B non vide
Range("B:B").SpecialCells(xlCellTypeConstants).Copy
'Coller les cellules non vide
word.Selection.PasteExcelTable LinkedToExcel:=False, WordFormatting:=False, RTF:=False

Application.CutCopyMode = True

End Sub

Bonsoir

ET simplement

word.Selection.Paste

Bonjour,

En en construisant le texte avant de l'insérer dans le document ?

Ici, j'utilise un signet nommé "Signet1" pour l'insertion du texte :

Sub Test()

    Dim AppWord As Object
    Dim Doc As Object
    Dim Plage As Range
    Dim Cel As Range
    Dim I As Long
    Dim Texte As String

    'défini la plage en colonne B de la feuille "Feuil1"
    With Worksheets("Feuil1"): Set Plage = .Range(.Cells(1, 2), .Cells(.Rows.Count, 2).End(xlUp)): End With

    'pour aller à la ligne sous le signet
    Texte = vbCrLf

    'construit le texte avec les valeurs de la plage
    For Each Cel In Plage: Texte = Texte & Cel.Value & vbCrLf: Next Cel

    'crée une instance de Word
    Set AppWord = CreateObject("Word.Application")

    With AppWord

        .Visible = True

        'ouvre un document
        Set Doc = .Documents.Open("C:\Users\Utilisateur\Test.docx")

        With Doc

            'insère le texte après le signet
            'Adapter le nom du signet !
            .Bookmarks("Signet1").Range.InsertAfter Texte

        End With

    End With

End Sub

bonjour

salut Theze au passage

la demande est étrange, ce qui amène la question : à quoi ça sert ?

amitiés

Super merci !

C'est une toute autre manière d'écrire le code ... parfois c'est vraiment ... d'être un néophyte dans un nouveau domaine.

Avec un peu d'adaptation à mon projet ca fonctionne très bien !

Pour répondre à JMD, je veux simplement mettre un bouton dans ma base de donné client pour que les éléments qui on été sélectionnés soient transférés sur une nouvelle feuille et puis que c'est infos filtrées soient facilement transférable vers un Word avec une entête et tous le Bazzzzard.

Encore merci pour votre temps

Rechercher des sujets similaires à "coller word tableau"