Somme de valeur doublon dans BDD

Bonjour à tous ,

J'aimerais avoir votre aide s'il vous plait pour le problème suivant : (voir fichier joint)

J'ai deux colonnes , les colonnes "K" et "Q" .Une fois avoir appliquer un filtre dans la colonne "Q", je voudrais supprimer les doublons de celle-ci mais en faisant la somme des valeurs des même doublons en colonne "K" sauf les "Isolé" qui eux doivent rester uniques.

le résultat attendu: avoir qu'une seule ligne par code contenu en colonne "Q" tout en ayant la somme des doublons de ce code en colonne "K" sans toucher aux doublons ayant une valeur "ISOLE" en colonne "Q"

Je me suis basé sur un code que Ausecour m'a écris cette semaine, mais je ne sais pas comment faire la somme de valeur des doublons dans une autre colonne

Ci-joint un extrait de la base de de donnée sur laquelle je travaille.

Je vous remercie par avance pour les conseils que vous pourriez me donner et pour votre disponibilité.

Bonjour,

Une piste mais fais un test sur une copie de ton classeur. Avant de lancer la procédure, tu dois trier ton tableau sur la colonne "REF_PBO" de façon à ce que les valeurs qu'elle contient soient regroupées :

Sub Test()

    Dim Dico As Object
    Dim Cle
    Dim Plage As Range
    Dim Cel As Range
    Dim I As Long

    With Worksheets("Feuil35"): Set Plage = .Range(.Cells(2, 17), .Cells(.Rows.Count, 17).End(xlUp)): End With

    Set Dico = CreateObject("Scripting.Dictionary")

    'stocke les noms des doublons dans le dico et totalise les valeurs
    For Each Cel In Plage: Dico(Cel.Value) = Dico(Cel.Value) + Cel.Offset(, -6).Value: Next Cel

    'suppression des doublons avec inscription des totaux
    For I = Plage.Count To 2 Step -1

        If Plage(I).Value <> "ISOLE" Then

            If Plage(I).Value = Plage(I - 1).Value Then
                Plage(I).EntireRow.Delete
            Else
                Plage(I).Offset(, -6).Value = Dico(Plage(I).Value)
            End If

        End If

    Next I

End Sub

Bonsoir le forum

Bonsoir Theze

Merci pour ton aide et pour ta disponibilité

Ton code me va impec

Cordialement