Probleme d'affichage

Bonjour all,

C'est encore moi avec mon userform de recherche ^^

J'ai enfin réussi à le faire tout marche super bien, sa affiche tout ce que j'ai besoin

Mais y a un souci ( en faillais bien un quand même), le bouton qui lance le userform se trouve sur la page de la base de donnée et tout marche bien par contre j'ai mis le bouton pour le lancer a partir de ma feuil tableau de bord. Le userform se lance mais ne trouve plus les données……

Je vois d'où viens le probleme, mais mes conaissance son assez limiter pour indiquer que les infos se trouve sur une autre page.

Private Sub CommandButton1_Click()

k = 0

Me.ListBox1.Clear

If Me.TextBox3 = "" Then Me.TextBox3 = "*"

If Me.TextBox2 = "" Then Me.TextBox2 = "*"

If Me.TextBox1 = "" Then Me.TextBox1 = "*"

For i = 2 To [A65000].End(xlUp).Row

If Cells(i, 1) Like "*" & Me.TextBox1 & "*" _

And Cells(i, 8) Like TextBox2 & "*" _

And Cells(i, 7) Like TextBox3 Then

Me.ListBox1.AddItem

Me.ListBox1.List(k, 0) = Cells(i, 1)

Me.ListBox1.List(k, 1) = Cells(i, 2)

Me.ListBox1.List(k, 2) = Cells(i, 3)

Me.ListBox1.List(k, 3) = Cells(i, 4)

Me.ListBox1.List(k, 4) = Cells(i, 5)

Me.ListBox1.List(k, 5) = Cells(i, 6)

Me.ListBox1.List(k, 6) = Cells(i, 7)

Me.ListBox1.List(k, 7) = Cells(i, 8)

Me.ListBox1.List(k, 8) = Cells(i, 9)

Me.ListBox1.List(k, 9) = Cells(i, 10)

k = k + 1

End If

Next i

End Sub

Private Sub UserForm_Click()

End Sub

J'oubliais pourquoi ca me met une erreure si je met une colone 11 ?

merci de votre aide

Bonjour,

Quand tu mets du code dans ton message, utilise le bouton [</>]

Il faut renseigner sur quelle feuille aller lire les données.

J'ai placé un With ... > au début > pour y faire référence tout au long du code, on place des . devant les range et cells. > puis, il ne faut pas oublier le End With à la fin.

Private Sub CommandButton1_Click()
Dim i As Integer
Dim K As Integer

   K = 0
   Me.ListBox1.Clear
   If Me.TextBox3 = "" Then Me.TextBox3 = "*"
   If Me.TextBox2 = "" Then Me.TextBox2 = "*"
   If Me.TextBox1 = "" Then Me.TextBox1 = "*"

   With Worksheets("MaBasedeDonnées")
      For i = 2 To .[A65000].End(xlUp).Row
         If .Cells(i, 1) Like "*" & Me.TextBox1 & "*" _
            And .Cells(i, 8) Like TextBox2 & "*" _
            And .Cells(i, 7) Like TextBox3 Then
            Me.ListBox1.AddItem
            Me.ListBox1.List(K, 0) = .Cells(i, 1)
            Me.ListBox1.List(K, 1) = .Cells(i, 2)
            Me.ListBox1.List(K, 2) = .Cells(i, 3)
            Me.ListBox1.List(K, 3) = .Cells(i, 4)
            Me.ListBox1.List(K, 4) = .Cells(i, 5)
            Me.ListBox1.List(K, 5) = .Cells(i, 6)
            Me.ListBox1.List(K, 6) = .Cells(i, 7)
            Me.ListBox1.List(K, 7) = .Cells(i, 8)
            Me.ListBox1.List(K, 8) = .Cells(i, 9)
            Me.ListBox1.List(K, 9) = .Cells(i, 10)
            K = K + 1
         End If
      Next i
   End With
End Sub

J'oubliais pourquoi ca me met une erreure si je met une colone 11 ?

Oui, listbox est limité par défaut à 10 colonnes (0 to 9).

Si mon souvenir est bon, on peut outrepasser en utilisant une variable tableau > que je ne sais pas faire.

ric

Bonjour,

je crois que c'est un truc comme ça :

Dim Tablo() As Variant
Tablo() = Range("A1:Z6").Value
ListBox1.List = Tablo

Il faut peut-être dimensionner la ListBox1 avant en nombre de colonne :

ListBox1.ColumnCount = 26

où 26 c'est pour l'exemple...

@ bientôt

LouReeD

Merci à vous ça marche super bien je peux avancer sur le reste

Mais le forum est là pour ça

Merci @ vous pour vos mercis !

@ bientôt

LouReeD