Erreur d'affichage
Bonjour,
Je construis ce tableau pour le calcul de dosage d'insuline pour un bébé diabétique.
Je fais cette formule =SI(C10<=80;D12+2;C10)
Lorsque C10 est vide, j'ai toujours le chiffre 2 dans ma case qui apparaît en c16 (conf tableau)onglet SEM1
Quelqu'un connait l'origine de l'erreur?
Merci à vous de votre aide.
Bonsoir,
Il n'y a pas d'erreur !
C10 est vide : =0
0 est <= 80
D12 est vide : =0
+2 —› 2
Cordialement.
Bonjour,
Merci de votre retour.
Je suis perdue
J'ai besoin de faire la formule suivante en c16:
Si b10 est inférieur ou égal a 80 alors faire c12+2 ou si b10 est supérieur a 80 alors mettre résultat de c12.
et il faut rajouter la règle en c16 que si b10 et b14 est supérieur à 250 deux jours d'affilés alors faire c16-2
Merci de votre aide
Bonjour,
Peux-tu expliquer calmement comment tu calcules le Bolus par rapport aux valeurs Insuline et Bolus des jours précédents (et quelles interactions entre petit déjeuner, collation, déjeuner, etc. ?), sans te focaliser sur les cellules, parce que là tu te mords la queue en incluant le résultat dans le calcul destiné à le produire, d'où référence circulaire.
Cordialement.
Mdr, calmement des bolus alors comment dire....
Pour le moment, je m'occupe du calcul du petit déjeuner, sans me préoccuper des autres repas dans la journée.
Le calcul du bolus est en rapport avec les résultats obtenus aux heures de la vielle, je m'explique:
- En fait, si la glycémie du lundi 8h est inférieure ou égale à 80, le bolus du mardi doit être le même nombre que celui de la veille à la même heure +2 (c'est de l'hypoglycémie)
- Si la glycémie du lundi 8h est supérieure à 80, c'est bon, on donne exactement la même dose pour le mardi 8h.
- Mais si elle est supérieure a 250 deux jours d'affilés, on doit prendre le bolus de la veille et faire -2 pour la dose du mercredi. (c'est de l'hyperglycémie)
Je créerai plus tard d'autres onglets avec d'autres semaines qui viendront piocher les infos du dimanche pour le lundi suivant.
Je sais pas si mes explications sont claires, c'est vraiment pas évident, et encore, c'est que le calcul du bolus!!! le reste on verra plus tard!!!
On va mettre la formule suivante sur le mardi (en C16) :
=SI(B10<>"";C12+((B10<=80)*(B10+B6<=250)-(B10+B6>250))*2;"Glycémie veille ?")Ne t'étonne pas de la référence à B6 (vide ou incluse dans une fusion, ce qui revient au même et est sans effet sur le résultat de la formule). Celle-ci est recopiable en C20, C24, etc.
Pour te fixer sa recopie en C20 va donner :
=SI(B14<>"";C16+((B14<=80)*(B14+B10<=250)-(B14+B10>250))*2;"Glycémie veille ?")Avant d'expliquer, il y a une ambiguïté à soulever : tu as dit supérieur à 250 2 jours précédents, mais tu additionnais...
donc est-ce la glycémie cumulée sur 2 jours (addition) ou chacun des deux jours doit être supérieur à 250 ?
Si c'est cette dernière hypothèse la bonne, il faudra refaire la formule.
Cette formule vérifie d'abord qu'une valeur glycémie veille a été saisie, sinon elle t'alerte en t'affichant la mention Glycémie veille ?. Si valeur glycémie existe, elle reprend la valeur du bolus veille, et si la somme des glycémie des 2 jours précédent est >250, diminue de 2, sinon si la glycémie veille est <=80, ajoute 2, sinon on laisse le bolus veille.
La formule calcule ces conditions sous la forme d'expressions booléennes qui renvoient VRAI ou FAUX, valeurs qui lors d'opérations deviennent 1 ou 0. Les opérations remplacent les SI pour combiner les conditions : une multiplication équivaut à un ET, une addition (ou soustraction) équivaut à un OU.
Note que (B14+B10>250) est VRAI, (B14+B10<=250) sera FAUX, et vice-versa.
Donc si glycémie veille + avant-veille >250, la formule va calculer :
BolusVeille + (1 * 0 - 1) * 2 = BolusVeille - 2 [si glycémie veille <=80]
ou BolusVeille + (0 * 0 - 1) * 2 = BolusVeille - 2 [si glycémie veille >80]
Si glycémie veille + avant-veille <=2500 :
si glycémie veille <=80 : BolusVeille + (1 * 1 - 0) * 2 = BolusVeille + 2
si glycémie veille >80 : BolusVeille + (0 * 1 - 0) * 2 = BolusVeille
Si la formule est à revoir, il faudra attendre ce soir car je suis sur le point de partir...
Cordialement.
wahou
je n'y serais jamais arrivée. Tu maîtrises excel à la perfection!
En revanche, c'est effectivement la dernière hypothèse ou chacun des 2 jours consécutifs doivent être a plus de 250!
Pour la B6, elle sera remplacée par ma cellule comme mit ci joint.
(J'ai appliqué ta formule, inséré d'autres onglets, et marier les cellules aux nouveaux onglets. (j'ai ma c12 en sem 2 qui merde)
Bonsoir,
Je vais réviser la formule en fonction des conditions indiquées, et je regarderai la suite, mais je viens juste de me réinstaller ailleur pour quelques jours et cela pourra peut-être attendre demain ?
Bonne soirée.
y'a aucun soucis c'est super gentil me m'aider en tout cas
Bonjour,
Voilà la formule rectifiée :
=SIERREUR(SI(B10<>"";C12+((B10<=80)*((B10>250)+(B6>250)<2)-((B10>250)+(B6>250)=2))*2;"?");"?")Où nous avons :
Cond1: veille (B10) <=80
Cond2.1: veille (B10) >250
Cond2.2: avant-veille (B6) >250
((Cond1)*((Cond2.1)+(Cond2.2)<2)-((Cond2.1)+(Cond2.2)=2))*2
va donner selon les cas 0, +2 ou -2 à ajouter au Bolus veille.
Je n'ai laissé ici que les "?" pour signaler l'absence de la valeur glycémie veille, et la formule est mise sous SIERREUR car afficherait #VALEUR! si pas de valeur la veille en raison de l'absence de valeur glycémie l'avant-veille...
Dans ton nouveau fichier, tu recrées des références circulaires ! Tu fais référence à la semaine 2 dans ta formule en semaine 1 !? C'est du passage en mode science fiction avec boucle temporelle !
Dans ton système il y aura toujours un point de départ, où tu saisis les valeurs initiales sans te référer à un jour précédent...
Tu y verrais plus clair pour formuler avec un tableau bâti de façon que chaque jour occupe une colonne avec séquence continue quelle que soit la durée... toutes les autres mention en lignes pour chacun des jours (les différentes mesures pour chaque tranche horaire).
Cordialement.
rolala c'est grandiose!!!!
Merciiiiiiiiiiiiii