Affecter une valeur déterminée à la même cellule de plusieurs feuilles

Bonjour,

je souhaite affecter un valeur que j'appelle ALPHA la cellule A1 par exemple, des feuilles "5", "7", "8", "11", et "16".

Comment faire au plus simple?

Merci.

Bonjour Corre, bonjour le forum,

Tu veux faire ça manuellement, par formule ou par macro ?

1. manuellement :

• Tu cliques sur l'onglet "5".
• En maintenant la touche [CTRL] enfoncée et tu cliques sur les onglets "7", "8", "11" et "16".
• Tu lâches la touche [CTRL], les onglets sont groupés.
• Tu cliques sur la cellule A1 et tu affectes une valeur.
• La valeur est affectée à tous les onglets du groupe de travail
• Tu dégroupes en cliquant sur n'importe quel onglet hors du groupe ("6" par exemple).

2. par formule :

• Tu groupes les onglets "7", "8", "11" et "16"
• Dans n'importe quel onglet du groupe tu sélectionnes la cellule A1
• Tu écris la formule : ='5'!A1
• Quand tu affectes une valeur à la cellule A1 de l'onglet "5", elle est automatiquement renvoyée sur la cellule A1 des onglets "7", "8", "11" et "16"

3. par macro : à placer dans le composant ThisWorkbook. Le changement se fera automatiquement quel que soit l'onglet édité :

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim TOS(1 To 5) As Worksheet 'déclare la variable TOS (Tableau des Onglets)
Dim O As Byte 'déclare la variable O (Onglet)

If Target.Address <> "$A$1" Then Exit Sub 'si le changement à lieu ailleurs que dans la cellule A1, sort de la procédure
Set TOS(1) = Worksheets("5") 'définit l'onglet TOS(1)
Set TOS(2) = Worksheets("7") 'définit l'onglet TOS(2)
Set TOS(3) = Worksheets("8") 'définit l'onglet TOS(3)
Set TOS(4) = Worksheets("11") 'définit l'onglet TOS(4)
Set TOS(5) = Worksheets("16") 'définit l'onglet TOS(5)

Select Case Sh.Name 'agit en fonction du nom de l'onglet actif
    Case "5", "7", "8", "11", "16" 'cas "5", "7", "8", "11" et "16"
        For O = 1 To UBound(TOS) 'boucle sur tous les onglet du tableau des onglets TOS
            If ActiveSheet.Name <> TOS(O).Name Then 'condition : si le nom de l'onglet actif (celui où la cellule a été modifiée) est différent de l'onglet de la boucle
                Application.EnableEvents = False 'empêche l'exécution des macros événementielle (pour éviter que ce code ne tourne en boucle)
                TOS(O).Range("A1").Value = Target.Value 'renvoie la valeur modifiée en A1 dans A1 de l'onglet de la boucle
            End If 'fin de la condition
        Next O 'prochain onglet de la boucle
        Application.EnableEvents = True 'permet l'exécution des macros événementielle (toujours réactiver a a fin !)
End Select 'fin de l'action en fonction du nom de l'onglet
End Sub