Copier/coller texte et image uniquement

Bonsoir,

Dans mon classeur excel je souhaite grâce à une macro copier/coller une cellule, mais uniquement le texte et son image (un pays avec un petit drapeau ) en conservant la mise en forme de destination.

J'ai essayé avec cette formule :

Range("C8").Copy

Range("Z6").PasteSpecial Paste:=xlPasteValues

Mais bien sur la photo n'apparait pas..

Quelle formule de Paste faut il utiliser ?

Merci d'avance

Corentin

Bonsoir,

Tu ne copies que le contenu de la cellule, pas l'image. Elle ne peut donc être collée, puisque pas copiée !

Cordialement.

Merci pour ta réponse

J'entends bien mais donc comment faire pour copier également l'image ?

Corentin

Au temps pour moi ! Tu copies bien l'image avec la cellule mais en ne collant que les valeurs tu exclues l'image du collage.

Il te faut tout coller.

Sub Test()
    With ActiveSheet
        .Range("C8").Copy .Range("Z6")
    End With
End Sub

Cordialement.

En effet les images apparaissent bien avec ce code

Sauf que la mise en forme source est conservée, je me suis peut être mal exprimé dans ma question, il me faut uniquement le texte et l'image, pas la mise en forme source.

Après je peux toujours demander à la macro de rechanger couleurs et bordures une fois le collage terminé mais ça rajoute pas mal de ligne au code... Surtout que j'ai pas mal de cellules à copier au final

Il faut alors traiter séparément la cellule et l'image...

On cherche l'image, on la duplique une fois trouvée, on positionne le double en Z6.

Sub Test()
    Dim shp As Shape, img As Shape
    With ActiveSheet
        For Each shp In .Shapes
            If shp.TopLeftCell.Address = "$C$8" Then
                Set img = shp.Duplicate
                img.Left = .Range("Z6").Left + shp.Left - .Range("C8").Left
                img.Top = .Range("Z6").Top + shp.Top - .Range("C8").Top
                Exit For
            End If
        Next shp
        .Range("Z6") = .Range("C8")
    End With
End Sub

Et on en profite pour ne plus copier mais affecter directement la valeur de C8 à Z6 !

Cordialement.

Un retour serait profitable ! L'absence de retour n'incite pas à continuer de répondre !

La formule est parfaite ça marche à merveille merci

Je marque le sujet comme résolu

C'est tout à fait satisfaisant de le savoir !