Récuperer un nom de tableau en double-cliquant

Bonsoir à toutes et à tous

Pourriez-vous m'aider sur un bout de code?

Voila ou je seche, je travaille sur une partie un onglet d'un fichier ou je me sers de la propriété "BeforeDoubleClick" pour lancer une userform

Sur l'onglet concerné il a plusieurs tableau structuré, le but c'est de ne pouvoir double-cliquer que sur la colonne A (nommée "Référence") de chaque tableau, j'ai commencé à travailler sur le code

'Déclaration des variables obligatoire
Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Dim NomTableau As Range

    NomTableau = ??

    Cancel = True

    If Not Application.Intersect(Target, Range(NomTableau & "[Référence]")) Is Nothing Then

        Load Userform_selection_action

        Userform_selection_action.Show

    End If

End Sub]

L'idée c'est que ce fichier va évoluer, à terme il y aura plus de tableau, c'est pour ca que dans ma syntaxe je me sers d'une variable pour définir le nom du tableau

Problème, après plusieurs essais je ne sais pas comment récuperer le nom du tableau à partir de la cellule double-cliquer

Merci d'avance à ceux qui se pencheront sur mon problème

Bonjour,

Une proposition à étudier et à adapter.

Cdlt.

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim lo As ListObject, lCol As Long
    If Target.CountLarge > 1 Then Exit Sub
    If Target.ListObject Is Nothing Then Exit Sub
    Set lo = Target.ListObject
    Cancel = True
    lCol = Target.Column - lo.HeaderRowRange(1).Column + 1
    If lCol = 1 Then
        MsgBox "OK"
    End If
End Sub

Bonsoir,

Aure proposition

Public tableau As ListObject

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    Cancel = True

    If Not Target.ListObject Is Nothing Then
        Set tableau = Target.ListObject
        If Not Intersect(Target, tableau.ListColumns("Référence").Range) Is Nothing Then
            Load Userform_selection_action

            Userform_selection_action.Show
        End If
    End If

End Sub

La référence au tableau concerné dans le code de ton UserForm se fera par la variable objet:

Sheets("nom de ta feuille").tableau

Merci à vous Jean-Eric et Thev, vos 2 méthodes fonctionnent à merveille

Je vais tacher de combler mes lacunes et étudier vos codes avec attentions

Merci encore et bonne soirée à vous

Streetchris