Mise à jour TCD dans feuille masquée

Bonjour,

J'aimerai savoir comment procéder pour a jour des tableaux croisés dynamiques dès l'ouverture du document dans une feuille qui est masquer ?

J'utilise ce code pour mettre à jour mon TCD et cela fonctionne.

Option Explicit
'code pour mis a jour tcd automatique via 1 celule pour gérer les filtres
Private Sub Worksheet_activate()

Dim pt As PivotTable
Dim iseason As String, i As Byte
    Application.ScreenUpdating = False
    iseason = Me.Cells(3, 1).Value
    For Each pt In Me.PivotTables
        With pt
            .PivotCache.Refresh
            .PageFields("Saison").ClearAllFilters
            On Error GoTo err_Handler
            .PageFields("Saison").CurrentPage = iseason
        End With
    Next pt
exit_Handler:
    Exit Sub
err_Handler:
    MsgBox "Il n'y a pas de données pour le filtre demandé.", vbInformation, "Saison inconnue"
    Resume exit_Handler

End Sub

Merci

Bien cordialement

Bonjour,

Personne ne peux me venir en aide ?

Bonjour,

dans le module ThisWorkbook du classeur :

Private Sub Workbook_Open()
    Update_PTs
End Sub

Dans un module standard :

Public Sub Update_PTs()
Dim ws As Worksheet
Dim pt As PivotTable
Dim strSeason As String

    Application.ScreenUpdating = False

    Set ws = ActiveWorkbook.Worksheets("A définir")
    strSeason = ws.Cells(3, 1).Value

    For Each pt In ws.PivotTables
        With pt
            .PivotCache.Refresh
            .PageFields("Saison").ClearAllFilters
            On Error GoTo err_Handler
            .PageFields("Saison").CurrentPage = strSeason
        End With
    Next pt

exit_Handler:
    Exit Sub

err_Handler:
    MsgBox "Il n'y a pas de données pour le filtre demandé.", vbInformation, "Saison inconnue"
    Resume exit_Handler

End Sub

Bonjour,

Merci de ta réponse.

Alors la merci beaucoup cela fonctionne comme je le souhaitai.

Vraiment merci.

Même quand le page est masquée cela fonctionne c'est super.

Bien cordialement,