Filtrer intégrer des données

Hello,

Je me permet de venir demander votre aide. toutes vos idées sont les bienvenues

J’ai un onglet : « DATA » je dois filtrer les données sur un mois, désigné sur onglet accueil.

Alors j’ai fais ça :

Sheets("Accueil").Select

Application.ScreenUpdating = False

no_mois = Cells(3, 4)

Sheets("DATA").Select

ActiveSheet.Range("$A$2:$J$37909").AutoFilter Field:=9, Criteria1:="no_mois"

Ca marche pas. mais ça marche !!!! quand je mets directement :

ActiveSheet.Range("$A$2:$J$37909").AutoFilter Field:=9, Criteria1:="6"

Je vous explique le reste de mon souci.

Je veux que la macro me copie le résultat filtrer et me le colle à la suite de la base de donné en onglet DATA 2.

Merci d’avance pour vos idées et votre aide

bonjour,

j'utilise la notion de tableaux nommés

j'espère que ma solution conviendra

je peux y apporter des modifications

Bonjour,

Une piste :

Sub Macro1()

    Dim Fe As Worksheet
    Dim Plage As Range
    Dim no_mois As Integer
    Dim Lgn As Long

    Set Fe = Worksheets("DATA")

    no_mois = Sheets("Accueil").Cells(3, 4).Value

    'défini la plage de A1 à Jx
    With Fe: Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 10).End(xlUp)): End With

    'défini la première ligne vide (celle qui va recevoir les entêtes)
    With Worksheets("DATA 2"): Lgn = .Cells(.Rows.Count, 1).End(xlUp).Row + 1: End With

    'filtrage
    Plage.AutoFilter 9, no_mois

    'copie le résultat
    Fe.AutoFilter.Range.EntireRow.Copy Worksheets("DATA 2").Range("A" & Lgn)

    'supprime le filtre
    Plage.AutoFilter

    'comme il faut coller les différents filtrages les uns à la suite des autres
    'et que la copie du filtrage se fait automatiquement avec les entêtes, il faut les supprimer
    Worksheets("DATA 2").Rows(Lgn).EntireRow.Delete

    'affiche le résultat
    Worksheets("DATA 2").Activate

End Sub

Bonsoir,

Une petite erreur de lecture.

Je reviens !

Cdlt.

Re,

Une proposition à étudier.

Cdlt.

Merci beaucoup pour toutes vos idées,c'est super sympa.

C'est une aide précieuse